home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 003 / daylog.arc / DAYLOG.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-09-01  |  19.1 KB  |  283 lines
  1. 1 '     Picture City Personal Computer Programmers Club Software Library
  2. 2 '
  3. 3 '     Program - DAYLOG - submitted by:
  4. 4 '
  5. 5 '     Michael Csontos, 3228 Livonia Center Road, Lima, New York 14485
  6. 6 '
  7. 7 '     August 18, 1982
  8. 8 '
  9. 9 '
  10. 110 PRINT "This program generates a form for recording data on a day by day basis with
  11. 120 PRINT "      each line labeled with the day and date.  Columns are set up and labeled
  12. 130 PRINT "      by the user.":PRINT
  13. 140 PRINT "The form will look something like the following:":PRINT
  14. 150 PRINT "             Date____|_Title_1_|_Title_2_|_Title 3_|_Title_4_|_Title 5_|
  15. 160 PRINT "             Mon.    |         |         |         |         |         |
  16. 170 PRINT "             Jan. 1  |         |         |         |         |         |
  17. 180 PRINT "             2001____|_________|_________|_________|_________|_________|
  18. 190 PRINT "             Tue.    |         |         |         |         |         |":PRINT
  19. 200 PRINT "The dates will run consecutively between starting and ending dates that you
  20. 210 PRINT "     enter, but you may select days of the week to be skipped.  This program
  21. 220 PRINT "     was written for a Epson MX-80 printer with Graphtrack.  Although no
  22. 230 PRINT "     special graphics features were used, some printer commands may have to be
  23. 240 PRINT "     changed for other printers.":PRINT
  24. 250 PRINT "You may have a set of titles and other format data filed on the disk.
  25. 260 DIM MTHNAME$(12):MTHNAME$(1)="JAN.":MTHNAME$(2)="FEB.":MTHNAME$(3)="MAR.":MTHNAME$(4)="APR.":MTHNAME$(5)="MAY.":MTHNAME$(6)="JUN.":MTHNAME$(7)="JUL.":MTHNAME$(8)="AUG.":MTHNAME$(9)="SEP.":MTHNAME$(10)="OCT.":MTHNAME$(11)="NOV.":MTHNAME$(12)="DEC."
  26. 270 KEY OFF:PRINT:PRINT "Do you have a format on file";:GOSUB 12000:ON A GOTO 310,280,270'YESORNOA
  27. 280 GOSUB 11000'retrieve file GETFILE
  28. 290 IF NOFILE=1 THEN GOTO 310 ELSE GOSUB 14000'modify? CHNGFORM
  29. 300 GOTO 520
  30. 310 PRINT "Please enter the date at which you want the form to start.":PRINT
  31. 320 GOSUB 1000' enter date  DATCHECK
  32. 330 STARTDATE$ = DAT$
  33. 340 PRINT "Please enter the date at which you want the form to end.":PRINT
  34. 350 GOSUB 1000' enter date  DATCHECK
  35. 360 ENDDATE$ = DAT$
  36. 370 PRINT "Do you want to skip any days of the week";:GOSUB 12000:ON A GOTO 390,380,370'YESORNOA
  37. 380 GOSUB 10000' input days to be skipped  SKIPDAY
  38. 390 GOSUB 8000' enter titles  TITLEIN
  39. 400 LINES=0:PRINT "This program is set up for 11 inch pages. You have four options for paging.":PRINT
  40. 410 PRINT "     1  30 lines per page regardless of content.
  41. 420 PRINT "     2  Start a new page for each new month.
  42. 430 PRINT "     3  Continuous chart with no paging.
  43. 440 PRINT "     4  The number of lines you choose (greater than 3 lines).
  44. 450 PRINT:INPUT "Please enter the number of the option you choose";LINES
  45. 460 IF LINES<1 OR INT(LINES)<>LINES OR LINES>4 THEN PRINT "Please enter a number corresponding to one of the options listed.":GOTO 400
  46. 470 IF LINES=4 THEN INPUT "Enter the number of lines you want per page";LINES
  47. 480 PRINT:PRINT "You may have a heading at the top of each page. Please enter the heading."
  48. 490 INPUT "Heading";HEADING$
  49. 500 PRINT "Do you want to save the format for this form";:GOSUB 12000:ON A GOTO 520,510,500'YESORNOA
  50. 510 GOSUB 13000'file the format variables  MAKEFILE
  51. 520 HOLD=0:TITLE$(0)="date    ":BADTITLE=0
  52. 530 WIDE=0:FOR W=0 TO 10:WIDE=WIDE+LEN(TITLE$(W))+1:NEXT W
  53. 540 LEFTMAR=132-WIDE:IF LEFTMAR<0 THEN 550 ELSE 570
  54. 550 Z=ABS(LEFTMAR)+1:PRINT "The chart is " Z " characters too wide. You should make your titles shorter.":BADTITLE=1:GOSUB 14000'modify? CHNGFORM
  55. 560 IF MODIFIED=1 THEN GOTO 520 ELSE LEFTMAR=0:BADTITLE=0
  56. 570 LEFTMAR$=STRING$(LEFTMAR," ")
  57. 580 BADHEAD=0:HEADGAP=8.5*(8-(LEFTMAR/17.16+LEN(HEADING$)/8.5+9/8.5))-1:IF HEADGAP<1 THEN 590 ELSE HEADMAR$=LEFTMAR$:GOTO 620
  58. 590 HEADGAP=2:HEADMAR=8.5*(8-(LEN(HEADING$)/8.5+9/8.5))-1:IF HEADMAR<1 THEN 600 ELSE HEADMAR$=STRING$(HEADMAR," "):GOTO 620
  59. 600 ZZ=INT(ABS(HEADMAR))+2:PRINT "The heading is " ZZ " characters too wide. You should make your heading shorter.":BADHEAD=1:GOSUB 14000'modify? CHNGFORM
  60. 610 IF MODIFIED=1  THEN GOTO 580 ELSE HEADGAP=1:HEADMAR$="":BADHEAD=0
  61. 620 PRINT "Is the printer ready to print the form";:GOSUB 12000:ON A GOTO 620,630,620'YESORNOA
  62. 630 PRINT "Pressing <H> will cause the printer to pause at the end of each page to allow ":PRINT "single sheet feeding.
  63. 640 PRINT "Pressing <Esc> will cause the printing to stop at the end of the date line being printed.":GOSUB 9000' set up printer  CHRTPRNT
  64. 650 DAT$=STARTDATE$:PAGENUM=0:GOSUB 2000'convert date to numbers DATTONUM
  65. 660 D=D-1:LINENUM=0:PAGENUM=PAGENUM+1
  66. 670 PRINTIME=0:ON ERROR GOTO 15000' printer error subroutine PRTERROR
  67. 680 LPRINT HEADMAR$ CHR$(14) HEADING$ SPC(HEADGAP) "Page" PAGENUM:LPRINT
  68. 690 LPRINT LEFTMAR$ CHR$(27)CHR$(45)CHR$(1);
  69. 700 FOR T=0 TO 10:LPRINT TITLE$(T);CHR$(156);:NEXT T:LPRINT
  70. 710 LPRINT CHR$(27)CHR$(45)CHR$(0);:ON ERROR GOTO 0
  71. 720 D=D+1:GOSUB 4000' check new date  DATGEN
  72. 730 IF DATINC=1 THEN GOTO 910
  73. 740 GOSUB 3000' find day of week  DAYNAME
  74. 750 FOR WKDY=1 TO 7:IF DAYNAME$ = DAYSKIP$(WKDY) THEN GOTO 780
  75. 760 NEXT WKDY
  76. 770 LINENUM=LINENUM+1:GOSUB 7000' print a form line  LINEFORM
  77. 780 IF ATE$ = ENDDATE$ THEN GOTO 850
  78. 790 ESC$=INKEY$:IF ESC$="H" OR ESC$="h" THEN HOLD=1
  79. 800 IF ESC$=CHR$(27) THEN PRINT "Form terminated. ";:FOR N=0 TO 15:DUMP$=INKEY$:NEXT:GOTO 860 ELSE IF ESC$<>"" THEN GOTO 790
  80. 810 IF LINES=1 AND LINENUM>=30 THEN GOTO 830
  81. 820 IF LINES>=4 AND LINENUM>=LINES THEN GOTO 830 ELSE GOTO 720
  82. 830 LPRINT CHR$(140):IF HOLD=1 THEN PRINT "Page " PAGENUM " finished. Press <Esc> to exit, any other key to continue.":FOR N=0 TO 15:DUMP$=INKEY$:NEXT:GOTO 840 ELSE GOTO 660
  83. 840 RESTART$=INKEY$:IF RESTART$=CHR$(27) THEN GOTO 860 ELSE IF RESTART$<>"" THEN GOTO 660 ELSE GOTO 840
  84. 850 PRINT "Form completed. ";:IF LINES=3 THEN GOTO 860 ELSE LPRINT CHR$(140)
  85. 860 GOSUB 14000:IF MODIFY=0 THEN GOTO 880'modify CHNGFORM
  86. 870 PRINT "Do you want to run this modification";:GOSUB 12000:ON A GOTO 890,520,870'YESORNOA
  87. 880 PRINT "Do want to run another copy of this form";:GOSUB 12000:ON A GOTO 900,620,880'YESORNOA
  88. 890 PRINT "Are you sure";:GOSUB 12000:ON A GOTO 870,900,890
  89. 900 PRINT "GOOD BYE":KEY ON:END
  90. 910 GOSUB 5000' increment to next month  NEXTDAY
  91. 920 GOSUB 4000' check incremented date  DATGEN
  92. 930 IF LINES=2 THEN GOTO 830 ELSE GOTO 740
  93. 1000 Z1000$=DATE$'                                           --
  94. 1010 INPUT "date";DAT$'                                       | subroutine
  95. 1020 ON ERROR GOTO 1070'        Converts input                |    to
  96. 1030 DATE$=DAT$'                to standard                   |   enter
  97. 1040 ON ERROR GOTO 0'           date format (mm-dd-yyyy)      |    and
  98. 1050 DAT$=DATE$:DATE$=Z1000$'   and returns it as DAT$        |   check
  99. 1060 RETURN'                                                  |    the
  100. 1070 IF ERR=5 THEN 1080 ELSE PRINT "DATCHECK TROUBLE":STOP'   |   date
  101. 1080 PRINT "Not a valid date. Try again.":RESUME 1010'       --
  102. 2000 Y=VAL(RIGHT$(DAT$,4))'                        --
  103. 2010 D=VAL(MID$(DAT$,4,2))'   dat$ as mm-dd-yyyy     |  subroutine
  104. 2020 M=VAL(LEFT$(DAT$, 2))'    to  M,D,Y,M$,D$,Y$    |     to
  105. 2030 M2030=M+100:D2030=D+100'                        |  decompose
  106. 2040 M$=STR$(M2030):D$=STR$(D2030):Y$=STR$(Y)'       |    dates
  107. 2050 M$=RIGHT$(M$,2):D$=RIGHT$(D$,2):Y$=RIGHT$(Y$,4)'|    into
  108. 2060 RETURN'                                       --  strings & numbers
  109. 3000 M3000=M:Y3000=Y'
  110. 3010 IF M3000>2 THEN 3030'
  111. 3020 M3000=M3000+12:Y3000=Y3000-1'
  112. 3030 N=2+D+M3000*2+Y3000+INT(Y3000/4)-INT(Y3000/100)+INT(Y3000/400)+INT(.6*(M3000+1))'
  113. 3040 ON 1+INT(1/2+(N/7-INT(N/7))*7) GOTO 3050,3060,3070,3080,3090,3100,3110'
  114. 3050 DAYNAME$="SAT.":RETURN'
  115. 3060 DAYNAME$="SUN.":RETURN'         Subroutine to give day of week
  116. 3070 DAYNAME$="MON.":RETURN'
  117. 3080 DAYNAME$="TUE.":RETURN'                     from
  118. 3090 DAYNAME$="WED.":RETURN'
  119. 3100 DAYNAME$="THU.":RETURN'            integers M, D, & Y.
  120. 3110 DAYNAME$="FRI.":RETURN'
  121. 4000 DATINC=0:Z4000$=DATE$'                                  --
  122. 4010 M$=STR$(M+100):D$=STR$(D+100):Y$=STR$(Y+10000)'           | subroutine
  123. 4020 M$=RIGHT$(M$,2):D$=RIGHT$(D$,2):Y$=RIGHT$(Y$,4)'          |    to
  124. 4030 ATE$=M$+"-"+D$+"-"+Y$'                                    |   form
  125. 4040 ON ERROR GOTO 4080'   Converts M,D, & Y integers          |    and
  126. 4050 DATE$=ATE$'           into ATE$ in form mm-dd-yyyy        |   check
  127. 4060 ON ERROR GOTO 0'      and M$,D$, & Y$ as mm, dd, & yyyy.  |     a
  128. 4070 DATE$=Z4000$:RETURN'  If invalid date, returns DATINC = 1.| standard
  129. 4080 IF ERR=5 THEN DATINC=1 ELSE PRINT "DATGEN TROUBLE":STOP'  |date format
  130. 4090 RESUME 4060'                                            --
  131. 5000 D=1:M=M+1:YEARLIM=0'                                 --
  132. 5010 IF M=13 THEN 5030'     Uses M, D, & Y.                 | subroutine
  133. 5020 RETURN'                Assumes end of old month.       |    for
  134. 5030 M=1:Y=Y+1'             Returns D=1,M+1,Y+1 as needed.  | incrementing
  135. 5040 IF Y>=2099 THEN 5060'  If Y exceeds 2099,              |    a
  136. 5050 RETURN'                      returns: YEARLIM = 1      |   date
  137. 5060 PRINT "Cannot go beyond year 2099"'                    |    by
  138. 5070 YEARLIM=1:RETURN'                                    --   one month
  139. 7000 ON ERROR GOTO 15000:COL0DL = LEN(TITLE$(0))-LEN(DAYNAME$)'
  140. 7010 IF D<10 THEN DD=3 ELSE DD=4'                                    |
  141. 7020 COL0ML = LEN(TITLE$(0))-(LEN(MTHNAME$(M))+DD)'                  |subrtn.
  142. 7030 COL0YL = LEN(TITLE$(0))-LEN(Y$)'                                |to
  143. 7040 COL0D$ = STRING$(COL0DL," ")'        needs TITLE$(t)            |print
  144. 7050 COL0M$ = STRING$(COL0ML," ")'              MTHNAME$(m)          |a
  145. 7060 COL0Y$ = STRING$(COL0YL," ")'              DAYNAME$             |three
  146. 7070 FOR C=1 TO 10'                             Y$                   |line
  147. 7080 COL$(C) = STRING$(LEN(TITLE$(C))," ")'     D                    |form
  148. 7090 NEXT C'                                    COL$(C) array must be|with
  149. 7100 LPRINT LEFTMAR$ DAYNAME$ COL0D$ CHR$(156);'dimensioned if C>10  |up
  150. 7110 FOR C=1 TO 10:LPRINT COL$(C) CHR$(156);:NEXT C:LPRINT'          |to
  151. 7120 LPRINT LEFTMAR$ MTHNAME$(M) D COL0M$ CHR$(156);'                |ten
  152. 7130 FOR C=1 TO 10:LPRINT COL$(C) CHR$(156);:NEXT C:LPRINT'          |columns
  153. 7140 LPRINT LEFTMAR$ CHR$(27) "-" CHR$(1);Y$;COL0Y$ CHR$(156);'      |defined
  154. 7150 FOR C=1 TO 10:LPRINT COL$(C) CHR$(156);:NEXT C'                 |by their
  155. 7160 LPRINT CHR$(27) "-" CHR$(0)'                                    |title
  156. 7170 ON ERROR GOTO 0:RETURN
  157. 8000 PRINT:PRINT "You may have up to ten titles. The maximum width is 132 characters but ten are"
  158. 8010 PRINT "taken up by dividing lines and ten by the date  (0)  column,  leaving 112.  By"
  159. 8020 PRINT "skipping a title you will have a double vertical dividing line. Extra dividing"
  160. 8030 PRINT "lines appear as a right-hand border.  The width of the column is determined by"
  161. 8040 PRINT "the title. To extend the width of the title beyond the title word use a period"
  162. 8050 PRINT "or quotation marks, eg.: .   123  . or  " CHR$(34) "   b   " CHR$(34) " .   Use (" CHR$(34) ")'s around a title
  163. 8055 PRINT "that has commas in it.
  164. 8060 TITLELENGTH=20
  165. 8070 FOR T=1 TO 10
  166. 8080 PRINT "Title for data column number";T;:INPUT TITLE$(T)
  167. 8090 TITLELENGTH=TITLELENGTH+LEN(TITLE$(T))
  168. 8100 PRINT "You have used " TITLELENGTH "characters. You have room for " 132-TITLELENGTH "more.":PRINT
  169. 8110 NEXT T
  170. 8120 RETURN
  171. 9000 ON ERROR GOTO 15000:LPRINT CHR$(27) "@";
  172. 9010 WIDTH "LPT1:",255
  173. 9020 LPRINT CHR$(27);CHR$(67);CHR$(0);CHR$(11);'ESC,FORM LENGTH,ELEVEN INCHES
  174. 9030 LPRINT CHR$(15);CHR$(27);CHR$(65);CHR$(8);'COMPRESSED,ESC,LINEFEED,8/72 ON
  175. 9040 LPRINT CHR$(27)+CHR$(85)+CHR$(1);         'ESC,UNIDIRECTIONAL PRINTING,ON
  176. 9050 ON ERROR GOTO 0:RETURN'
  177. 10000 DAY$(1)="Saturday":DAY$(2)="Sunday":DAY$(3)="Monday":DAY$(4)="Tuesday":DAY$(5)="Wednesday":DAY$(6)="Thursday":DAY$(7)="Friday"
  178. 10010 SKIPDAY$(1)="SAT.":SKIPDAY$(2)="SUN.":SKIPDAY$(3)="MON.":SKIPDAY$(4)="TUE.":SKIPDAY$(5)="WED.":SKIPDAY$(6)="THU.":SKIPDAY$(7)="FRI."
  179. 10020 FOR SKN=1 TO 7'                                          subroutine to
  180. 10030 PRINT "Do you want to skip "DAY$(SKN);:INPUT SKIP$'      return an array
  181. 10040 IF SKIP$="Y" THEN DAYSKIP$(SKN)=SKIPDAY$(SKN):GOTO 10090'of day and null
  182. 10050 IF SKIP$="y" THEN DAYSKIP$(SKN)=SKIPDAY$(SKN):GOTO 10090'strings as the
  183. 10060 IF SKIP$="N" THEN DAYSKIP$(SKN)="":GOTO 10090'           var. DAYSKIP$
  184. 10070 IF SKIP$="n" THEN DAYSKIP$(SKN)="":GOTO 10090'
  185. 10080 PRINT "Please answer y or n.":GOTO 10030'   requires no common variables
  186. 10090 NEXT'                                       uses SKN,DAYS$(1-7),SKIP$
  187. 10100 RETURN'                                     SKIPDAY$(1-7)
  188. 11000 ON ERROR GOTO 11130:NOFILE=0
  189. 11010 PRINT:PRINT "The following files are available.":FILES "*.frm"
  190. 11020 ON ERROR GOTO 0
  191. 11030 PRINT:PRINT "What is the filename of the one you want to use":INPUT "(if none type NONE)";FILENAME$
  192. 11040 IF FILENAME$="NONE" OR FILENAME$="none" OR FILENAME$="None" THEN NOFILE=1:RETURN
  193. 11050 FILENAME$=FILENAME$+".frm"
  194. 11060 ON ERROR GOTO 11150:OPEN FILENAME$ FOR INPUT AS #1
  195. 11070 INPUT #1,STARTDATE$,ENDDATE$
  196. 11080 FOR N=1 TO 7:INPUT #1,DAYSKIP$(N):NEXT
  197. 11090 FOR N=1 TO 10:INPUT #1,TITLE$(N):NEXT
  198. 11100 INPUT #1,LINES,HEADING$
  199. 11110 CLOSE #1:ON ERROR GOTO 0
  200. 11120 RETURN
  201. 11130 IF ERR=53 THEN 11140 ELSE PRINT "GETFILE TROUBLE":STOP
  202. 11140 PRINT "There are no files for this program on this disk.":NOFILE=1:RESUME 11120
  203. 11150 IF ERR = 52 THEN PRINT "That is not a correct filespec, try again":RESUME 11020
  204. 11160 IF ERR = 62 THEN PRINT "Bad file data. You are trying to read from the wrong file. Try again.":RESUME 11000
  205. 11170 IF ERR = 53 THEN 11180 ELSE PRINT "GETFILE TROUBLE":STOP
  206. 11180 PRINT "That isn't one of the files available, try again.":RESUME 11020
  207. 12000 INPUT Q$'                         subroutine which returns    --
  208. 12010 IF Q$="n" THEN A=1:RETURN'         A = 1, 2, or 3 in response    |
  209. 12020 IF Q$="N" THEN A=1:RETURN'         to a yes or no question.      |
  210. 12030 IF Q$="y" THEN A=2:RETURN'                                       |
  211. 12040 IF Q$="Y" THEN A=2 ELSE A=3:PRINT "Please answer Y, y, N, or n."'|
  212. 12050 RETURN'                                                       --
  213. 13000 ON ERROR GOTO 13160
  214. 13010 PRINT:FILES "*.frm"
  215. 13020 PRINT:PRINT "The above file names have been used."
  216. 13030 ON ERROR GOTO 0
  217. 13040 PRINT "What filename do you want to use? (Up to 8 characters, no extension;Type NONE
  218. 13050 INPUT "to return to printing without saving modifications.):  FILENAME";FILENAME$
  219. 13060 IF FILENAME$="none" OR FILENAME$="None" OR FILENAME$="NONE" THEN RETURN
  220. 13070 IF LEN(FILENAME$)>8 THEN PRINT "Filename too long. Try again. Do not use extension. Extension {.FRM} is added.":GOTO 13040
  221. 13080 FILENAME$=FILENAME$+".frm"
  222. 13090 ON ERROR GOTO 16000' disk error subroutine DSKERROR
  223. 13100 OPEN FILENAME$ FOR OUTPUT AS #1
  224. 13110 WRITE #1,STARTDATE$,ENDDATE$
  225. 13120 FOR N=1 TO 7:WRITE #1,DAYSKIP$(N):NEXT
  226. 13130 FOR N=1 TO 10:WRITE #1,TITLE$(N):NEXT
  227. 13140 WRITE #1,LINES,HEADING$
  228. 13150 CLOSE #1:ON ERROR GOTO 0:RETURN
  229. 13160 IF ERR = 53 THEN 13170 ELSE PRINT "MAKEFILE TROUBLE":STOP
  230. 13170 PRINT "There are no format files on this disk":RESUME 13030
  231. 14000 PRINT "Do you want to modify this form";:GOSUB 12000:ON A GOTO 14010,14020,14000'YESORNOA
  232. 14010 MODIFIED=0:RETURN
  233. 14020 MODIFIED=1:IF BADTITLE=1 THEN GOTO 14150
  234. 14030 IF BADHEAD=1 THEN GOTO 14280
  235. 14040 PRINT "The current starting date is "STARTDATE$". Do you want to change it";:GOSUB 12000:ON A GOTO 14080,14050,14040'YESORNOA
  236. 14050 PRINT "New ";:GOSUB 1000' enter date DATCHECK
  237. 14060 GOSUB 2000' generate numerical date constants  DATTONUM
  238. 14070 STARTDATE$=DAT$
  239. 14080 PRINT "The current ending date is " ENDDATE$ ". Do you want to change it";:GOSUB 12000:ON A GOTO 14110,14090,14080'YESORNOA
  240. 14090 PRINT "New ";:GOSUB 1000' enter date DATCHECK
  241. 14100 ENDDATE$=DAT$:GOTO 14110
  242. 14110 PRINT "Presntly the days to be skipped are: ";:FOR N=1 TO 7:PRINT DAYSKIP$(N) ", ";:NEXT:PRINT
  243. 14120 PRINT "Do you want to change these";:GOSUB 12000'YESORNOA
  244. 14130 ON A GOTO 14150,14140,14110
  245. 14140 GOSUB 10000' reenter skip days SKIPDAY
  246. 14150 PRINT "The present set of column titles is:"
  247. 14160 FOR N=1 TO 10:PRINT TITLE$(N):NEXT:PRINT
  248. 14170 PRINT "Do you want to change these";:GOSUB 12000:ON A GOTO 14220,14180,14150'YESORNOA
  249. 14180 FOR CHG = 1 TO 10
  250. 14190 PRINT USING "The title for column ## is:   "; CHG :PRINT SPC(29) TITLE$(CHG) :PRINT "Do you want to change it";:GOSUB 12000:ON A GOTO 14210,14200,14190'YESORNOA
  251. 14200 GOSUB 14330:INPUT "New title";TITLE$(CHG):GOSUB 14350
  252. 14210 NEXT CHG
  253. 14220 IF BADTITLE=1 THEN GOTO 14300
  254. 14230 PRINT "The form length options are 1. 31 lines; 2. months; 3. continuous; 4. specified."
  255. 14240 PRINT "The current option is " LINES ". Do you want to change it";:GOSUB 12000:ON A GOTO 14280,14250,14230'YESORNOA
  256. 14250 INPUT "New option number";LINES
  257. 14260 IF LINES<1 OR INT(LINES)<>LINES OR LINES>4 THEN PRINT "Please enter  1, 2, 3, or 4.":GOTO 14230
  258. 14270 IF LINES=4 THEN INPUT "Number of lines";LINES
  259. 14280 PRINT "The present heading for the chart is:":PRINT:PRINT HEADING$:PRINT "Do you want to change it";:GOSUB 12000:ON A GOTO 14300,14290,14280'YESORNOA
  260. 14290 GOSUB 14340:INPUT "New heading";HEADING$:GOSUB 14350:PRINT:PRINT
  261. 14300 PRINT "Do you want to save these modifications";:GOSUB 12000:ON A GOTO 14320,14310,14300'YESORNOA
  262. 14310 GOSUB 13000'file the new variables MAKEFILE
  263. 14320 RETURN
  264. 14330 X=CSRLIN:LOCATE 25,1:PRINT "Note: You may edit and enter an isolated line above instead of retyping it!":LOCATE X-4,30:PRINT "12345678901234567890123456789012345678901234567890":LOCATE X,1:RETURN
  265. 14340 X=CSRLIN:LOCATE 25,1:PRINT "Note: You may edit and enter an isolated line above instead of retyping it!":LOCATE X-4,1:PRINT "1234567890123456789012345678901234567890123456789012345678901234567890123456789":LOCATE X,1:RETURN
  266. 14350 X=CSRLIN:LOCATE 25,1:BLANK$=STRING$(79," "):PRINT BLANK$;:LOCATE X,1:RETURN
  267. 15000 IF ERR = 27 THEN PRINT "Printer off or out of paper. Program will continue when problem is corrected.":RESUME
  268. 15010 IF ERR = 68 THEN PRINT "Printer unavailable or disabled. Program will continue when problem is corrected.":RESUME
  269. 15020 IF ERR = 25 THEN PRINT "Printer fault. Program will continue when problem is corrected.":RESUME
  270. 15030 IF ERR = 24 THEN PRINTIME=PRINTIME+1 ELSE PRINT "PRTERROR problem:on error GOTO 0:stop
  271. 15040 IF PRINTIME < 2 THEN RESUME ELSE PRINT "Printer off line. Program will continue when problem is corrected.":PRINTIME=0:RESUME
  272. 16000 IF ERR=24 THEN PRINT "No disk in drive? Device timeout.":GOTO 16090
  273. 16010 IF ERR=57 THEN PRINT "I/O error. Try another disk.":GOTO 16090
  274. 16020 IF ERR=61 THEN PRINT "Disk full. Try another disk.":GOTO 16090
  275. 16030 IF ERR=64 THEN PRINT "Bad file name. ";:INPUT "Try entering the complete filespec (with extension).";FILENAME$:RESUME
  276. 16040 IF ERR=67 THEN PRINT "Too many files in directory. Try another disk to temoroarily save your data.":GOTO 16090
  277. 16050 IF ERR=68 THEN PRINT "Disk drive unavailable.":GOTO 16090
  278. 16060 IF ERR=70 THEN PRINT "You have write protected this disk!":GOTO 16090
  279. 16070 IF ERR=71 THEN PRINT "No disk in drive or door not closed.":GOTO 16090
  280. 16080 IF ERR=72 THEN PRINT "Disk Media Error. Try another disk.":GOTO 16090
  281. 16090 PRINT "Program will continue when problem is corrected.":RESUME
  282. 65000 ' SAVE"DAYLOG.bas",a
  283.